Le temps : delay(), millis() et les événements

Compter le temps en millisecondes¶

L'ESP32 compte le temps en millisecondes (ms) : 1 seconde = 1 000 ms.

Fréquence et période¶

Pour un phénomène qui se répète, on parle de fréquence (combien de fois par seconde, en hertz, Hz) ou de période (combien de temps dure un cycle). Les deux sont liées :

période (ms) = 1 000 ÷ fréquence (Hz)

Une LED qui clignote 2 fois par seconde (2 Hz) a une période de 1 000 ÷ 2 = 500 ms : 250 ms allumée, 250 ms éteinte.

delay() : la sieste¶

digitalWrite(LED, HIGH);
delay(500);                    // le programme dort 500 millisecondes
digitalWrite(LED, LOW);

Simple et efficace… tant qu'il n'y a qu'une seule chose à faire. Pendant la sieste, l'ESP32 n'écoute plus rien : ni la manette, ni les boutons.

millis() : l'horloge¶

millis() donne le nombre de millisecondes écoulées depuis le démarrage de la carte. Au lieu de dormir, on compare l'heure :

unsigned long dernierChangement = 0;
bool allumee = false;

void loop() {
  if (millis() - dernierChangement >= 500) {   // 500 ms sont passées ?
    dernierChangement = millis();
    allumee = !allumee;                        // on inverse
    digitalWrite(LED, allumee ? HIGH : LOW);
  }
  // ici, le programme continue : il peut lire la manette en même temps !
}

C'est comme vérifier sa montre plutôt que de faire une sieste : « est-ce que c'est l'heure ? Non ? Alors je fais autre chose et je regarde de nouveau dans un instant. »

Plusieurs chronos en même temps¶

Le grand avantage de millis() : chaque tâche peut avoir son propre chrono. Voir la mise en pratique plus bas, avec deux LEDs à des rythmes différents.

Le temps qui avance plus ou moins vite¶

Dans le banc d'essai de la mission 1, les scénarios ne lisent pas millis() directement : ils lisent une horloge maison, qui avance plus ou moins vite selon la vitesse choisie avec les flèches ↑ ↓. C'est comme ça qu'on accélère un clignotement sans toucher à son code.

Les événements : réagir au bon moment¶

Un bouton appuyé une demi-seconde est vu 50 fois par un loop() qui tourne toutes les 10 ms. Pour ne réagir qu'une fois, on compare avec ce qu'on avait vu au tour précédent :

bool avant = false;

void loop() {
  bool maintenant = manette->a();
  if (maintenant && !avant) {    // appuyé maintenant, pas appuyé avant :
    Serial.println("✕ !");       // il VIENT d'être enfoncé
  }
  avant = maintenant;
}

C'est exactement ce que fait la fonction vientDAppuyer du banc d'essai de la mission 1.

Les étapes : une petite machine à états¶

Pour un enchaînement (« boum, attendre, boum, attendre… ») sans delay(), on note à quelle étape on en est, et l'heure de départ. À chaque tour de loop(), on regarde si c'est l'heure de passer à l'étape suivante. C'est la technique du battement de cœur de la mission 1 : le programme garde une variable etapeCoeur et un tableau des moments où vibrer.

Mise en pratique : deux LEDs, deux rythmes¶

Sur le montage de la piste d'atterrissage, fais clignoter D18 toutes les 300 ms et D19 toutes les 700 ms, en même temps. Impossible avec delay(), facile avec deux chronos :

const int LED_A = 18, LED_B = 19;
unsigned long chronoA = 0, chronoB = 0;
bool etatA = false, etatB = false;

void setup() {
  pinMode(LED_A, OUTPUT);
  pinMode(LED_B, OUTPUT);
}

void loop() {
  unsigned long maintenant = millis();

  if (maintenant - chronoA >= 300) {      // la LED A a son propre chrono
    chronoA = maintenant;
    etatA = !etatA;
    digitalWrite(LED_A, etatA);
  }
  if (maintenant - chronoB >= 700) {      // la LED B aussi
    chronoB = maintenant;
    etatB = !etatB;
    digitalWrite(LED_B, etatB);
  }
}

Regarde bien : de temps en temps, les deux LEDs changent en même temps. Tous les combien ? Le plus petit nombre divisible à la fois par 300 et par 700 : 2 100 ms.

Exercices¶

Où ça sert dans l'atelier¶

• Mission 0 · Écrire le programme : le clignotement avec delay().
• Mission 1 · Comment il est construit : scénarios avec millis(), boutons avec vientDAppuyer.
• Mission 1 · Défi 2 · La manette qui bat comme un cœur : des vibrations au bon moment, sans bloquer.

Pour aller plus loin¶

• 🇫🇷 Introduire le temps, cours Arduino d'Eskimon : delay(), millis() et un chenillard.
• 🇬🇧 Blink Without Delay, l'exemple officiel Arduino.
• 🇬🇧 La référence officielle : delay() et millis().